mse version: 0.3.8
game: vs
full name: New Style EM
short name: New Style
installer group: VS System/New style/Normal
icon: card-sample.png
position hint: 001

version: 2009-01-18
depends on:
	package: vs.mse-game
	version: 2008-10-26
depends on:
	package: vs-common.mse-include
	version: 2007-09-06
depends on:
	package: vs-standard-official.mse-symbol-font
	version: 2008-01-03

card background: white
card width: 375
card height: 523
card dpi: 150

############################################################## Extra scripts
init script:
	con_opt_template_1 := {
			if   styling.con_optional == "c-left" then "ccoccard2.png"
			else                  		           "ccoccard.png"
	}
	con_opt_template_2 := {
			if   styling.con_optional == "c-left" then "ccoccard2.png"
			else                  		           "ccoccard.png"
	}
	con_opt_template_3 := {
			if   styling.con_optional == "c-left" then "ccoccard2.png"
			else                  		           "ccoccard.png"
	}
	card_shape := { "new" }
	
	text_filter := 
		# step 1 : Remove all automatic tags
		tag_remove_rule(tag: "<sym-auto>") +
		tag_remove_rule(tag: "<i-auto>")   +
		tag_remove_rule(tag: "<b-auto>")   +
		remove_tag@(tag: "<nospellcheck") +
		# step 2 : Reminder text for keywords
		expand_keywords@(
			condition: {
				correct_case
			}
			default_expand: {
				chosen(choice:if correct_case then mode else "lower case", set.automatic_reminder_text)
			},
			combine: {
				# un-bold parameters
				keyword := tag_contents(keyword, tag:"<param",
				              contents: {"</b-auto>{input}<b-auto>"})
				reminder := process_english_hints(reminder)
				# the combined result
				"<b-auto>{keyword}</b-auto>"
				 + if expand then "<atom-reminder-{mode}> ({reminder})</atom-reminder-{mode}>"
			}) +
		# step 3 : Expand shortcut words ~ and CARDNAME
		replace_rule(
			match: "~|~THIS~|CARDNAME",
			in_context: "(^|[[:space:]])<match>",
			replace: "<atom-cardname>&</atom-cardname>"
			) +
		# step 4 : Fill in atom fields
		tag_contents_rule(
			tag: "<atom-cardname>",
			contents: { if card.name=="" then "CARDNAME" else card.name }
			) +
		# step 5a: add arrow/diamond/dot symbols
		replace_rule(
			match: "->|>>>|@|<>|•",
			replace: "<sym-auto>&</sym-auto>") +
		# step 5b: Majority of affiliation symbols
		replace_rule(
			match: "Activate|Avengers|B.P.R.D.|Brotherhood|Crime Lords|Defenders|Doom|Fantastic Four|Gotham Knights|Green Lantern|Hellfire Club|Heralds of Galactus|Horsemen of Apocalypse|Invaders|JLA|JSA|Kree|Marvel Knights|Masters of Evil|Negative Zone|Planet|Shadowpact|Shi'ar|Sinister Syndicate|Skrull|Speed Force|Spider-Friends|Team Superman|Thule Society|Thunderbolts|Teen Titans|Underworld|Warbound|X-Men",
			replace: "<sym-auto>&</sym-auto>") +
		# step 5c: SHIELD Variations
		replace_rule(
			match: "S.H.I.E.L.D.|SHIELD|Shield",
			replace: "<sym-auto>Shield</sym-auto>") +
		#X#if contains(card.shape, match:"old") then symbol_filter else new_symbols
		# step 7a : Bold keywords without reminder text
		replace_rule(
		 	match: "<kw[^>]*>[^<]+</kw-a>",
	 		replace: "<b-auto>&</b-auto>") +
		# step 7b : Bold keywords with reminder text
		replace_rule(
		 	match: "<kw[^>]*>[^<]+</kw-A>",
	 		replace: "<b-auto>&</b-auto>") +
		# step 8 : Italic reminder text
		replace_rule(
		 	match: "[(][^)\n]*[)]?",
			in_context: "(^|[[:space:]])<match>|<atom-keyword><match>",
		 	replace: "<i-auto>&</i-auto>")

############################################################## Set info fields
############################################################## Extra style
styling field:
	type: package choice
	name: text box symbols
	match: vs-standard-*.mse-symbol-font
	initial: vs-standard-official.mse-symbol-font
styling field:
	type: boolean
	name: foils
	description: Use foil backgrounds?
	initial: no
styling field:
	type: boolean
	name: watermarkings
	description: Use watermarks?
	initial: no
styling field:
	type: choice
	name: con optional
	description: Use which concealed-optional?
	initial: c-left
	choice: c-left
	choice: c-right
styling style:
	con optional:
		render style: both
		choice images:
			c-left: ccoccard2.png
			c-right: ccoccard.png
############################################################## Card fields
card style:
	############################# Background stuff
	card type:
		left:	0
		top:	0
		width:	375
		height:	523
		z index: -2
		render style: image
		popup style: in place
		choice images:
			characters visible character:					cvchcard.png
			characters visible character dual:				cvchcard.png
			characters visible character dual (new):			cvchcard.png
			characters hidden concealed:					chcocard.png
			characters hidden concealed dual:				chcocard.png
			characters hidden concealed dual (new):				chcocard.png
			characters concealed-optional concealed-optional character:	{ con_opt_template_1(value) }
			characters concealed-optional concealed-optional dual:		{ con_opt_template_2(value) }
			characters concealed-optional concealed-optional dual (new):	{ con_opt_template_3(value) }
			equipment visible equipment:					eveqcard.png
			equipment concealed equipment:					eceqcard.png
			equipment concealed-optional equipment:				eoeqcard.png
			location:							locard.png
			plot twist:							ptcard.png
			planet:								plcard.png
	############################# Name line
	full name:
		left: 82
		top : 20
		width: 230
		height: 30
		alignment: middle center shrink-overflow
		padding bottom: 0
		z index: 4
		font:
			name: Percolator Expert TM
			size: 30
			scale down to: 6
			color: rgb(247,239,231)
			separator color: rgb(247,239,231)
		symbol font:
			name: vs-standard-official
			size: 15
			alignment: middle center
	cost:
		left: 25
		top : 29
		width: 25
		height: 41
		alignment: bottom center
		font:
			name: BadhouseBoldNumbers
			size: 35
			color: rgb(252,217,121)
			shadow color: rgb(0,0,0)
			shadow displacement x: 2
			shadow displacement y: 2
		z index: 4
		visible: { card.card_type!="planet" }
		padding top: 0
	############################# Image
	image:
		left:	18
		top:	73
		width:	{ if card.card_type=="planet" then 0 else 339 }
		height: { if card.card_type=="planet" then 0 else 255 }
		mask:	image-mask.png
		visible: { card.card_type!="planet" }
		z index: 1
	card symbol:
		left: 315
		top : 33
		height: 30
		width: 35
		render style: image
		choice images:
			Marvel:	marvel.png
			DC-new:	dcnew.png
			DC-old:	/vs-common.mse-include/dcold.png
			Hellboy: hellboy.png
			Other...: { set.custom_logo }
		z index: 3
	############################# Type Bar
	type text full:
		left:	22
		top:	317
		width:	{ if card.card_type=="planet" then 0 else 332 }
		height: { if card.card_type=="planet" then 0 else 12 }
		font:
			name: BankGothic Md BT
			size: 8
			color: rgb(0,0,0)
		visible: { is_character() or is_equipment() }
		alignment: middle center shrink-overflow
		z index: 3
	type bar:
		left:	19
		top:	317
		width:	{ if card.card_type=="planet" then 0 else 338 }
		height: { if card.card_type=="planet" then 0 else 13 }
		visible: { card.type_text != "" }
		render style: image
		choice images:
			type bar: type-bar.png
		z index: 2
	############################# Version
	version full:
		left: 80
		top : 51
		width: 230
		height: 18
		alignment: middle center shrink-overflow
		z index: 4
		font:
			name: Percolator Expert TM
			size: 16
			scale down to: 8
			color: rgb(247,239,231)
			separator color: rgb(247,239,231)
	############################# Card ID
	number line:
		left: { if card.card_type=="planet" then 165 else 106 }
		top : { if card.card_type=="planet" then 468 else 481 }
		width: 45
		height: 15
		z index: 4
		font:
			name: Eurostile-Black-DTC
			size: 8
			color:
				script: if card.rarity=="common"   then rgb(255,255,255)
				else    if card.rarity=="uncommon" then rgb(151,183,201)
				else    if card.rarity=="rare"     then rgb(253,215,125)
				else 	if card.rarity=="promo"    then rgb(255,20,20)
				else rgb(255,255,255)
	promo outliner:
		left: { if card.card_type=="planet" then 164 else 105 }
		top : { if card.card_type=="planet" then 467 else 480 }
		width: 45
		height: 15
		visible: { card.rarity=="promo" }
		z index: 3
		font:
			name: Eurostile
			size: 8
			color: rgb(255,255,255)
			weight: bold
	promo outliner 2:
		left: { if card.card_type=="planet" then 166 else 107 }
		top : { if card.card_type=="planet" then 469 else 482 }
		width: 45
		height: 15
		visible: { card.rarity=="promo" }
		z index: 3
		font:
			name: Eurostile
			size: 8
			color: rgb(255,255,255)
			weight: bold
	rarity:
		left: { if card.card_type=="planet" then 180 else 120 }
		top: { if card.card_type=="planet" then 458 else 470 }
		width: 23
		height: 25
		z index: 5
		render style: image hidden
		choice images:
			common:	  /vs-common.mse-include/rarity-common.png
			uncommon: /vs-common.mse-include/rarity-uncommon.png
			rare:	  /vs-common.mse-include/rarity-rare.png
			promo:    /vs-common.mse-include/rarity-promo.png
	############################# Affiliation
	team full:
		left: { if card.card_type=="planet" then 20 else 19 }
		top : { if card.card_type=="planet" then 441 else 327 }
		height: 28
		width: 338
		font:
			name: Gill Sans MT Condensed
			size: 12
			color:
				script:	if is_concealed()	then rgb(23,4,6)
				else	if is_equipment()	then rgb(82,82,82)
				else    if is_location()	then rgb(0,48,33)
				else    if is_plot_twist()	then rgb(28,47,87)
				else if card.card_type=="planet" then rgb(243,217,105)
				else                                  rgb(41,0,0)
		alignment: middle center
		z index: 4
		padding left:   4
		padding top:    4
		padding right:  4
		padding bottom: 4
	############################# Text box
	rule text:
		left: { if card.card_type=="planet" then 72 else 20 }
		top : { if card.card_type=="planet" then 123 else 353 }
		width: { if card.card_type=="planet" then 236 else 335 }
		height: { if card.card_type=="planet" then 305 else if card.flavor_text!="" then 95 else 100 }
		font:
			name: Eurostile
			italic name: EurostileObl-Normal
			size: 11
			scale down to: 6
			color: rgb(0,0,0)
		symbol font:
			name: { styling.text_box_symbols }
			size: 14
			alignment: middle center
		alignment: middle left
		z index: 3
		padding left:   3
		padding top:    5
		padding right:  2
		padding bottom: 6
		line height hard: 1.4
	flavor text:
		left: 90
		top : 449
		width: { if card.card_type=="planet" then 0 else 225 }
		height: { if card.card_type=="planet" then 0 else 25 }
		font:
			name: EurostileObl-Normal
			size: 10
			scale down to: 6
			color: rgb(0,0,0)
		alignment: bottom center
		z index: 3
		visible: { card.card_type!="planet" }
		padding left:   2
		padding top:    0
		padding right:  2
		padding bottom: 2
		line height hard: 1
	watermark:
		left: { if watermark_narrow() then 150 else if watermark_wide() then 112 else 147 }
		top:  367
		width: { if watermark_narrow() then 75 else if watermark_wide() then 165 else 90 }
		height: 90
		visible: { styling.watermarkings }
		render style: image
		include file: /vs-common.mse-include/watermarks
		z index: 4
	############################# Attack/defence
	attack:
		z index: 4
		left:	24
		top:	448
		width:	{ if card.card_type=="planet" then 0 else 30 }
		height:	{ if card.card_type=="planet" then 0 else 47 }
		visible: { is_character() }
		z index: 4
		alignment: bottom center shrink-overflow
		font:
			name: BadhouseBoldNumbers
			size: 35
			color: rgb(252,217,121)
			shadow color: rgb(0,0,0)
			shadow displacement x: 3
			shadow displacement y: 0
	defence:
		z index: 4
		left:	323
		top:	448
		width:	{ if card.card_type=="planet" then 0 else 30 }
		height:	{ if card.card_type=="planet" then 0 else 47 }
		visible: { is_character() }
		z index: 4
		alignment: bottom center shrink-overflow
		font:
			name: BadhouseBoldNumbers
			size: 35
			color: rgb(145,199,219)
			shadow color: rgb(0,0,0)
			shadow displacement x: -3
			shadow displacement y: 0
	############################# Copyright stuff
	illustrator:
		left: 169
		top : 476
		width: 133
		height: 15
		alignment: middle left shrink-overflow
		z index: 4
		font:
			name: BankGothic Md BT
			size: 6
			color: rgb(255,255,255)
		visible: { card.card_type!="planet" }
	copyright:
		left: { if card.card_type=="planet" then 139 else 103 }
		top : { if card.card_type=="planet" then 479 else 493 }
		width: { if card.card_type=="planet" then 100 else 200 }
		height: { if card.card_type=="planet" then 20 else 10 }
		z index: 4
		alignment: middle center
		font: 
			name: Eurostile
			size: 6
			color: rgb(255,255,255)
	############################ For New style cards
	playarea:
		left: 320
		top : 333
		height: 15
		width: 29
		z index: 4
		visible: { is_character() or is_equipment() }
		render style: image list
		choice images:
			visible: visible.png
			concealed: concealed.png
			both: concealop.png
	flightrange:
		left: 65
		top : 460
		height: 39
		width: 18
		z index: 4
		visible: { is_character() }
		render style: image list
		choice images:
			flight: flight.png
			range: range.png
			both: flightrange.png
	ongoing:
		left: 23
		top : 473
		height: 13
		width: 18
		z index: 5
		visible: { is_plot_twist() }
		render style: image list
		choice images:
			ongoing: ongoing.png
	affiliation:
		right: { 184 + card_style.team_full.content_width * -0.5 }
		top : 332
		height: 16
		width: 27
		z index: 5
		alignment: middle right
		render style: image
		include file: /vs-common.mse-include/affiliations
	affiliation2:
		right: { card_style.team_full.content_width * 0.5 + 217 }
		top : 332
		height: 16
		width: 27
		z index: 5
		alignment: middle left
		render style: image
		include file: /vs-common.mse-include/affiliations
############################################################## Extra card fields
extra card field:
	type: choice
	name: foil layer
	choice: foil
	editable: false
extra card style:
	foil layer:
		left: 0
		top : 0
		width: { if styling.foils=="no" then 0 else 375 }
		height: { if styling.foils=="no" then 0 else 523 }
		z index: 8
		render style: image
		choice images:
			foil: /vs-common.mse-include/foil.png
		visible: { styling.foils }
